reset
clear
set encoding iso_8859_1
set term svg size 800,400 font "Arial,8"
set datafile separator " "
set xlabel 'Jahr' offset 0,3
set title "Anteil an der Weltbevölkerung\nnach Jahr und Kontinent"
set key invert reverse Left outside
set yrange [ 0 : 100 ] noreverse nowriteback
unset ytics
set grid layerdefault front
set border 3
set style fill transparent solid 0.5 noborder
set style data line
set xrange [-400:2000]
set ylabel "% der Gesamtbevölkerung"
set key invert reverse right outside autotitle columnhead
set xtics rotate by -75 font "Arial,8" out offset -0.5
set xtics add ("400 v. Chr." -400, "200 v. Chr." -200, "0" 0, "100 n. Chr." 100, "200" 200, "400" 400, "" 500, "600" 600, "800" 800, "1000" 1000, "1100" 1100, "1200" 1200, "1300" 1300, "1400" 1400, "1500" 1500, "1600" 1600, "1700" 1700, "1800" 1800, "1900" 1900, "2000" 2000)
set output 'world_population.svg'
plot 'data.dat' using 1:($2+$3+$4+$5+$6+$7) w filledcurve x1 lc rgb 'green',\
'' using 1:($2+$3+$4+$5+$6) w filledcurve x1 lc rgb 'brown',\
'' using 1:($2+$3+$4+$5) w filledcurve x1 lc rgb 'blue',\
'' using 1:($2+$3+$4) w filledcurve x1 lc rgb 'red',\
'' using 1:($2+$3) w filledcurve x1 lc rgb 'orange',\
'' using 1:($2) w filledcurve x1 lc rgb 'yellow'
unset output